blob: 38fca0d03e9d0ee4b59c162c2709c68720013417 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: hashworks <hashworks@archlinux.org>
pkgname=chatblade
pkgdesc="A CLI Swiss Army Knife for ChatGPT"
pkgver=0.2.1
pkgrel=1
arch=("any")
url="https://github.com/npiv/chatblade"
license=("GPL3")
# https://github.com/npiv/chatblade/blob/main/requirements.txt
depends=(
"python"
"python-importlib-metadata"
"python-setuptools"
"python-aiohttp"
"python-aiosignal"
"python-async-timeout"
"python-attrs"
"python-certifi"
"python-charset-normalizer"
"python-frozenlist"
"python-idna"
"python-markdown-it-py"
"python-mdurl"
"python-multidict"
"python-openai"
"python-pygments"
"python-yaml"
"python-regex"
"python-requests"
"python-rich"
"python-tiktoken"
"python-tqdm"
"python-urllib3"
"python-yarl"
)
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('7e5cfedb0b9b9d724c15df24f71adae0025fb4cac473e72469a5c0037228494c')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Use remote assets
sed -i 's#<img src="assets/\([^"]*\)">#<img src="'${url}'/raw/v'${pkgver}'/assets/\1">#g' README.md
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
python setup.py install --root="${pkgdir}" -O1 --skip-build
}
|