blob: 5f283e1313b9ca1bc3f7dfeda970dab1a1670bbb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Nebulosa <nebulosa2007-at-yandex-dot-ru>
pkgname=chawan-git
pkgver=r1938.3cc7f9d
pkgrel=1
pkgdesc="Web browser for your terminal"
arch=(x86_64)
url="https://git.sr.ht/~bptato/${pkgname%-git}"
license=(Unlicense)
depends=(
bash
gcc-libs
glibc
libseccomp
ncurses
openssl
zlib
)
makedepends=(
git
nim
pandoc
)
optdepends=('termcap: to use display computer terminals in a device-independent manner')
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
options=(!debug)
source=(${pkgname%-git}::git+$url)
b2sums=('SKIP')
pkgver() {
cd ${pkgname%-git}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname%-git}
make submodule
}
build() {
cd ${pkgname%-git}
make all
}
package() {
cd ${pkgname%-git}
install -vDm644 UNLICENSE -t "$pkgdir"/usr/share/licenses/${pkgname%-git}/
install -vd "$pkgdir"/usr/share/man/man{1,5}
make DESTDIR="$pkgdir" PREFIX="/usr" LIBEXECDIR="$pkgdir"/usr/lib/${pkgname%-git} install
}
|