blob: 4576023e3a580809b1824344e56932008f431847 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
_pkgname='chkservice'
pkgname="${_pkgname,,}-git"
pkgver=0.3.r1.gea40b14
pkgrel=1
pkgdesc='Systemd units manager with ncurses terminal interface'
arch=('x86_64')
url='https://github.com/linuxenko/chkservice'
license=('GPL3')
depends=('libsystemd')
makedepends=('cmake' 'git')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
git -C "${_pkgname}" describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
export CFLAGS+=" ${CPPFLAGS}"
export CXXFLAGS+=" ${CPPFLAGS}"
cmake -B 'build' -S "${_pkgname}" \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-Wno-dev
make -C 'build'
}
package() {
make DESTDIR="${pkgdir}" PREFIX='/usr' -C 'build' install
install -Dvm644 "${_pkgname}/README.md" -t "${pkgdir}/usr/share/doc/${_pkgname}"
}
# vim: ts=2 sw=2 et:
|