blob: 7a26ddb421e6f9502134d287ddd5fc84743f07af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: joelvaz0x01 <joelvaz dot whitehat at gmail dot com>
_pkgbase=chordpro
_pkgbasever=6.070
pkgname=${_pkgbase}-cli
pkgver=${_pkgbasever}.7
pkgrel=2
_pkgdownload=App-Music-ChordPro-${pkgver}
_wxver=3.005
pkgdesc="A lyrics and chords formatting program (CLI)"
arch=('any')
url="https://chordpro.org/"
_ghurl="https://github.com/ChordPro/chordpro"
license=('Artistic-2.0')
depends=('perl')
makedepends=('perl-local-lib' 'cpanminus')
provides=(chordpro)
conflicts=(chordpro)
source=(
"${_ghurl}/releases/download/R${_pkgbasever}/${_pkgdownload}.tar.gz"
"chordpro.sh"
)
sha256sums=(
'47f3f202e6afc0f524d0e29ca4776b5eb6b7f3660aeb4b18e499cda7a0f40312'
'259db24404125459b563f049f746c6844cf8eab46728d0c9935cc36765cb722d'
)
build() {
cd "${srcdir}/${_pkgdownload}"
export PERL_MM_USE_DEFAULT=1
eval "$(perl -I "${srcdir}" -Mlocal::lib="${srcdir}")"
cpanm --notest --local-lib="${srcdir}" --verbose --installdeps .
perl Makefile.PL
make install
}
check() {
cd "${srcdir}/${_pkgdownload}"
export PERL_MM_USE_DEFAULT=1
eval "$(perl -I "${srcdir}" -Mlocal::lib="${srcdir}")"
make test
}
package() {
install -d "${pkgdir}/opt/${_pkgbase}/lib"
cp -a "${srcdir}/${_pkgdownload}/lib"/* "${pkgdir}/opt/${_pkgbase}/lib"
cp -a "${srcdir}/lib/perl5"/* "${pkgdir}/opt/${_pkgbase}/lib"
# install binary
install -Dm755 "${srcdir}/${_pkgdownload}/script/chordpro.pl" "${pkgdir}/opt/${_pkgbase}/bin/chordpro"
# install wrapper script
install -Dm755 "${srcdir}/chordpro.sh" "${pkgdir}/usr/bin/chordpro"
sed -i "s|/bin/true|/opt/${_pkgbase}/bin/chordpro|" "${pkgdir}/usr/bin/chordpro"
# install man page
gzip -n -f "${srcdir}/man/man1/chordpro.1p"
install -Dm644 "${srcdir}/man/man1/chordpro.1p.gz" "${pkgdir}/usr/share/man/man1p/chordpro.1p.gz"
# install license
install -Dm644 "${srcdir}/${_pkgdownload}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgbase}/LICENSE"
}
|