blob: ed6237cfa87df0e8e4b466aa9e88294f8ea7b9f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
# Contributor: klepz <felipe.junger@aluno.ufabc.edu.br>
# Contributor: Dave Blair <mail@dave-blair.de>
# Contributor: James An <james@jamesan.ca>
# Contributor: Mateus Rodrigues Costa <charles [dot] costar [at] gmail [dot] com>
pkgname=chrome-remote-desktop
pkgver=66.0.3359.12
pkgrel=2
pkgdesc="Access other computers or allow another user to access your computer securely over the Internet"
arch=("x86_64")
url="https://chrome.google.com/webstore/detail/gbchcmhmhahfdphkhkmpfmihenigjmpp"
license=("BSD")
depends=("gtk3" "libxss" "nss" "python2" "python2-psutil" "xorg-server-xvfb" "xorg-setxkbmap" "xorg-xauth" "xorg-xdpyinfo")
install="${pkgname}.install"
source=("${pkgname}.deb::http://dl.google.com/linux/direct/${pkgname}_current_amd64.deb"
"${pkgname}.service"
"crd")
sha256sums=("3bc6e153cb98b67f605df3be89d4971369ceecf96955d12d226cc858babe2e0d"
"e5da5ae89b5bc599f72f415d1523341b25357931b0de46159fce50ab83615a4b"
"27dee2d383e6bd993fe0557d5c222fa80ab6d16d43775dedff6218713c7a1c06")
pkgver() {
bsdtar -xf control.tar.gz -O control | grep "^Version: " | cut -f2 -d' '
}
build() {
cd "${srcdir}"
msg2 "Extracting data from debian package"
bsdtar -xf data.tar.xz -C .
msg2 "Removing unnecessary .deb related files"
rm -R "${srcdir}/etc/cron.daily"
rm -R "${srcdir}/etc/init.d"
rm -R "${srcdir}/etc/pam.d"
}
package() {
cd "${srcdir}"
install -d "${pkgdir}/etc"
install -d "${pkgdir}/opt"
cp -r "${srcdir}/etc/"* "${pkgdir}/etc"
cp -r "${srcdir}/opt/"* "${pkgdir}/opt"
msg2 "Packaging copyright file"
install -Dm644 "${srcdir}/usr/share/doc/${pkgname}/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
msg2 "Adding systemd user service file"
install -Dm644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/user/${pkgname}.service"
msg2 "Adding runnable crd command"
install -Dm755 "${srcdir}/crd" "${pkgdir}/usr/bin/crd"
msg2 "Creating symlinks for Chromium compatibility"
install -dm755 "${pkgdir}/etc/chromium/native-messaging-hosts"
for _file in $(find "${pkgdir}/etc/opt/chrome/native-messaging-hosts" -type f); do
_filename=${_file##*/}
if [[ ! -f "/etc/chromium/native-messaging-hosts/${_filename}" ]]; then
ln -s "/etc/opt/chrome/native-messaging-hosts/${_filename}" "${pkgdir}/etc/chromium/native-messaging-hosts/${_filename}"
fi
done
msg2 "Setting uid root to user-session command"
chmod u+s "${pkgdir}/opt/google/${pkgname}/user-session"
}
|