blob: da185d09dcc707e9b61caf6827338c7a2153b9e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Doug Newgard <scimmia at archlinux dot org>
pkgname=chromium-widevine
pkgdesc='A browser plugin designed for the viewing of premium video content'
pkgver=4.10.2652.0
_chrome_ver=113.0.5672.126
pkgrel=1
epoch=1
arch=('x86_64')
url='https://www.widevine.com/'
license=('custom')
options=('!strip')
source=("https://dl.google.com/linux/deb/pool/main/g/google-chrome-stable/google-chrome-stable_${_chrome_ver}-1_amd64.deb")
sha256sums=('6a624904d7a7ee2ec27e637164ddddd102cc799ffa9c14a05f88762363200bf1')
prepare() {
bsdtar -x --strip-components 4 -f data.tar.xz opt/google/chrome/WidevineCdm
}
pkgver() {
awk 'match($0,/"version": "([0-9.]*)"/,a) {print a[1];}' WidevineCdm/manifest.json
}
package() {
depends=('gcc-libs' 'glib2' 'glibc' 'nspr' 'nss')
install -dm755 "$pkgdir/usr/lib/chromium/"
cp -a WidevineCdm "$pkgdir/usr/lib/chromium/"
find "$pkgdir" -name '*.so' -exec chmod +x {} \;
install -Dm644 WidevineCdm/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
# backward compatibility
ln -s WidevineCdm/_platform_specific/linux_x64/libwidevinecdm.so "$pkgdir/usr/lib/chromium/libwidevinecdm.so"
}
|