blob: ac9ac76086f796d5597ac9f27b0d6ba52fb0220e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Doug Newgard <scimmia at archlinux dot org>
pkgname=chromium-widevine
pkgdesc='A browser plugin designed for the viewing of premium video content'
pkgver=4.10.1679.0
_chrome_ver=84.0.4147.135
pkgrel=1
epoch=1
arch=('x86_64')
url='https://www.widevine.com/'
license=('custom')
provides=("chromium-widevine-dev=$pkgver")
conflicts=('chromium-widevine-dev')
options=('!strip')
source=("https://dl.google.com/linux/deb/pool/main/g/google-chrome-stable/google-chrome-stable_${_chrome_ver}-1_amd64.deb")
sha256sums=('d2ba6d0264c8b47a2df65b9196fe34f9c72163e3a2558462be067f54f90069aa')
prepare() {
bsdtar -x --strip-components 4 -f data.tar.xz opt/google/chrome/WidevineCdm
}
pkgver() {
awk 'match($0,/"version": "([0-9.]*)"/,a) {print a[1];}' WidevineCdm/manifest.json
}
package() {
depends=('gcc-libs' 'glib2' 'glibc' 'nspr' 'nss')
install -dm755 "$pkgdir/usr/lib/"chromium{,-dev}/
cp -a WidevineCdm "$pkgdir/usr/lib/chromium/"
ln -s ../chromium/WidevineCdm "$pkgdir/usr/lib/chromium-dev/WidevineCdm"
install -Dm644 WidevineCdm/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
# backward compatibility
ln -s WidevineCdm/_platform_specific/linux_x64/libwidevinecdm.so "$pkgdir/usr/lib/chromium/libwidevinecdm.so"
}
|