blob: 41bdac73a10dc36cda6ddfac5a90e1bcc3dbe75f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=chrysalis
pkgdesc='Graphical configurator for Kaleidoscope-powered keyboards'
pkgver=0.9.4
pkgrel=1
arch=(x86_64)
url="https://github.com/keyboardio/${pkgname^}"
license=(GPL3)
_electron=electron17
depends=("$_electron"
fuse2
uucp)
makedepends=(git
jq
moreutils
node-gyp
yarn)
_archive="${pkgname^}-$pkgver"
source=("$url/archive/v$pkgver/$_archive.tar.gz"
"$pkgname.sh")
sha256sums=('59b8188b6f856c92a49937e521859f0c5b2a3dc42c86df57c2d5b33b3c8c2ca5'
'9de3ff052ca4600862b8663b93bf2b4223cf2e637995c67e1fe4cb4ed893b39f')
_yarnargs="--cache-folder '$srcdir/node_modules'"
prepare() {
local _electronVersion=$($_electron --version | sed -e 's/^v//')
cd "$_archive"
jq 'del(.devDependencies["electron"])' package.json | sponge package.json
yarn $_yarnargs install --frozen-lockfile --ignore-scripts
yarn $_yarnargs add -D --no-lockfile --ignore-scripts electron@$_electronVersion
}
build() {
cd "$_archive"
yarn $_yarnargs run build:linux
}
package() {
sed -E "s/electron/$_electron/" "$pkgname.sh" |
install -Dm0755 /dev/stdin "$pkgdir/usr/bin/$pkgname"
cd "$_archive"
local _dist=dist/linux-unpacked/resources
install -Dm0644 -t "$pkgdir/usr/lib/$pkgname/" "$_dist/app.asar"
cp -a "$_dist/static" "$pkgdir/usr/lib/$pkgname"
}
|