PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: schaap137 <dojo86@gmail.com>
pkgname=chugins-git
pkgver=1.3.5.2.r86.g9ed524f
pkgrel=5
pkgdesc="Repository for ChuGins (to use with chuck)"
arch=('i686' 'x86_64')
url="https://github.com/ccrma/chugins"
license=('GPL')
depends=('chuck')
makedepends=('cpio' 'findutils' 'git')
source=("$pkgname"::"git://github.com/ccrma/chugins.git")
sha256sums=('SKIP')

pkgver() {
  # The version
  cd "$srcdir/$pkgname"
  git describe --long --tags | sed "s/\([^-]*-g\)/r\1/;s/-/./g" | sed "s/chugins.//g"
}

prepare() {
  cd "$srcdir/$pkgname"
  # Change JACK to PULSE if you use chuck-pulse, or comment out the next line if you use chuck-alsa
  sed -e 's/__LINUX_ALSA__/__LINUX_JACK__/g' -i **/makefile.linux
  sed -e 's/\/usr\/local\/lib/\/usr\/lib/g' -i **/makefile.linux makefile
}

build() {
  cd "$srcdir/$pkgname"
  make linux
}

package() {
  cd "$srcdir/$pkgname"
  mkdir -p "$pkgdir"/usr/lib/chuck
  install -Dm755 **/*.chug "$pkgdir"/usr/lib/chuck/
  mkdir -p "$pkgdir"/usr/share/doc/chuck/examples/chugins
  find . -type f -regex '.*\.\(md\|wav\|ck\)' | cpio -p -d -v -u "$pkgdir"/usr/share/doc/chuck/examples/chugins/
}