PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: Core_UK <dev@coredev.uk>

pkgname=cider
_pkgname=Cider
_pkgbranch=stable
pkgver=1.5.9
pkgrel=5
pkgdesc="Project Cider. An open-source Apple Music client built from the ground up with Vue.js and Electron. Compiled from the GitHub repositories ${_pkgbranch} branch."
arch=("armv7h" "i686" "x86_64")
url="https://github.com/ciderapp/${_pkgname}.git"
license=("GPL")
depends=('gtk3' 'nss')
makedepends=('git' 'npm' 'pnpm' 'python')
optdepends=('libnotify: Playback notifications')
source=(
    "git+https://github.com/CiderApp/${_pkgname}.git#branch=${_pkgbranch}"
    "cider.desktop"
)
sha256sums=('SKIP'
    'c41e9b1019411019fce8509e32f770edf33c9e864bf707c30ffe2e3f2dcf1571')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    chmod +x ./resources/version.sh
    GITHUB_REF_NAME=${_pkgbranch} ./resources/version.sh | sed 's/\-/./g'
}

build() {
    cd "${srcdir}/${_pkgname}"
    git submodule update --init --recursive

    echo "store-dir=.pnpm-store" >>.npmrc

    echo "Building ${_pkgname} on v${pkgver} : [Install Build Dependencies] | Build | Done"
    pnpm install --frozen-lockfile

    echo "Building : Install Build Dependencies | [Build] | Done"
    pnpm dist --linux dir

    echo "Building : Install Build Dependencies | Build | [Done]"
}

package() {
    cd "${srcdir}/${_pkgname}"

    # Desktop File
    install -Dm644 "${srcdir}/${pkgname%-git}.desktop" "${pkgdir}/usr/share/applications/${pkgname%-git}.desktop"
    # Install the icon
    install -Dm644 "${srcdir}/${_pkgname}/resources/icons/icon.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/${pkgname%-git}.png"
    # Install the build files
    install -d "$pkgdir/opt/"
    install -d "$pkgdir/usr/bin/"
    cd ${srcdir}/${_pkgname}/dist/linux-unpacked
    mkdir "${pkgdir}/opt/${pkgname%-git}"
    cp -r --preserve=mode * "${pkgdir}/opt/${pkgname%-git}"
    ln -sf "/opt/${pkgname%-git}/${pkgname%-git}" "${pkgdir}/usr/bin/${pkgname%-git}"
    # License and Readme
    install -d "$pkgdir/usr/share/licenses" "$pkgdir/usr/share/doc"
    install -Dm644 "${srcdir}/${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    install -Dm644 "${srcdir}/${_pkgname}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}