blob: b8ea1c926424be60b4556dcde056dc200afeb8ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: robertfoster
# Contributor: FabioLolix
pkgname=cie-middleware-git
pkgver=1.3.2.r3.2beb5d5
pkgrel=1
pkgdesc="Middleware della CIE (Carta di Identità Elettronica) per Linux (mio fork)"
arch=(x86_64 i686 pentium4 arm armv6h armv7h aarch64)
url="https://developers.italia.it/it/cie"
license=('BSD')
depends=('crypto++' 'openssl' 'pcsclite' 'java-runtime')
makedepends=('git' 'gradle' 'meson')
install="${pkgname%-git}.install"
source=("${pkgname%-git}::git+https://github.com/M0Rf30/${pkgname%-git}-linux")
pkgver() {
cd "$srcdir/${pkgname%-git}"
printf "%s" "$(git describe --tags --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
build() {
cd "${srcdir}/${pkgname%-git}"
gradle -b cie-java/build.gradle standalone
cd libcie-pkcs11/
meson builddir
meson configure -Dprefix=/usr builddir
meson compile -C builddir
}
package() {
cd "${srcdir}/${pkgname%-git}"
# Java Application
install -Dm755 cie-java/bin/libs/CIEID-standalone.jar \
"${pkgdir}/usr/share/cieid/cieid.jar"
install -Dm644 "data/cieid.desktop" \
"${pkgdir}/usr/share/applications/cieid.desktop"
install -Dm755 data/logo.png \
"${pkgdir}/usr/share/pixmaps/cieid.png"
install -Dm755 "data/cieid.sh" \
"${pkgdir}/usr/bin/cieid"
install -Dm644 LICENSE \
"${pkgdir}/usr/share/licenses/cieid/LICENSE"
# Lib for PKCS11
DESTDIR="${pkgdir}" meson install -C libcie-pkcs11/builddir
}
md5sums=('SKIP')
|