summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7eb6eb806b983f0f4336351d4e822af99471a456 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# $Id$
# Maintainer: Realex
# Based on cinnamon-session PKGBUILD

_pkgname=cinnamon-session
pkgname=${_pkgname}-git
pkgver=126.8c1b918
pkgrel=1
pkgdesc="The Cinnamon Session Handler"
arch=(i686 x86_64)
license=(GPL LGPL)
depends=('cinnamon-desktop-git' 'upower' 'libcanberra' 'libsm')
makedepends=('intltool' 'mesa' 'json-glib' 'xtrans' 'gnome-common' 'git')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
options=('!emptydirs')
install=${pkgname}.install
url="http://cinnamon.linuxmint.com/"
source=(${_pkgname}::git+https://github.com/linuxmint/cinnamon-session.git)
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  echo $(git rev-list --count master).$(git rev-parse --short master)
}

build() {
  cd $_pkgname

  ./autogen.sh --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/cinnamon-session \
      --sbindir=/usr/bin --disable-schemas-compile --enable-systemd
  make
}

package() {
  cd $_pkgname
  make DESTDIR="$pkgdir" install
}