blob: fc665a04d310bd65d04a93d354a198503c619340 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Jef Roosens
pkgname='cinny-desktop'
pkgver='3.0.0'
pkgrel='1'
pkgdesc='Matrix client focusing primarily on a simple, elegant and secure interface.'
arch=('x86_64')
url='https://cinny.in/'
license=('MIT')
# https://tauri.studio/v1/guides/getting-started/prerequisites#1-system-dependencies
depends=(
'webkit2gtk'
'openssl'
'gtk3'
'appmenu-gtk-module'
'libappindicator-gtk3'
'librsvg'
'libvips'
'sqlite'
'gst-plugins-good'
)
makedepends=('rust' 'nodejs' 'npm')
# This makes sure dirty builds still pull down the newest version
source=("${pkgname}-${pkgver}.zip::https://github.com/cinnyapp/cinny-desktop/releases/download/v${pkgver}/cinny-desktop-v${pkgver}.zip")
sha256sums=('a6d5c1ea56df4fc7570006d820f9bed6d8a77753e56fb60025b26b95a89e7db4')
sha512sums=('bf7e2fc2ddf14414d71f8ddf5e0ace0c51bb0f670f4357d6567febb3799ccf5d665567a960625cb72cf7c76f635ed5926eb3317b0c625a50611466acbe7a5731')
install="${pkgname}.install"
build() {
cd "${pkgname}"
msg2 'Installing Node dependencies...'
cd 'cinny' && npm --legacy-peer-deps ci
cd .. && npm ci
msg2 'Running Tauri build...'
# With the default memory limit, the build fails due to having insufficient
# memory available. 4GB seems to be enough for now.
NODE_OPTIONS=--max_old_space_size=4096 npm run tauri build -- --bundles 'deb'
}
package() {
ar x "${pkgname}/src-tauri/target/release/bundle/deb/cinny_${pkgver}_amd64.deb" 'data.tar.gz'
tar xzf 'data.tar.gz' -C "${pkgdir}"
}
# vim: ft=bash
|