blob: 25dddc709548a233a7084492d60627cab9c0a2d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Tim Schumacher <timschumi@gmx.de>
# Contributor: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
# Contributor: ceri
_pkgbase='citra'
pkgbase="$_pkgbase-git"
pkgname=("$_pkgbase-git" "$_pkgbase-qt-git")
pkgver=r6896.a96f0f516
pkgrel=1
pkgdesc="An experimental open-source Nintendo 3DS emulator/debugger"
arch=('i686' 'x86_64')
url="https://github.com/citra-emu/citra/"
license=('GPL2')
makedepends=('git' 'cmake' 'sdl2' 'qt5-base' 'shared-mime-info' 'desktop-file-utils' 'qt5-multimedia')
source=("$_pkgbase::git+https://github.com/citra-emu/citra")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgbase"
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgbase"
mkdir -p build
git submodule init
git submodule update --init --recursive
}
build() {
cd "$srcdir/$_pkgbase/build"
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DUSE_SYSTEM_CURL=ON \
-DUSE_DISCORD_PRESENCE=ON
make
}
check() {
cd "$srcdir/$_pkgbase/build"
make test
}
package_citra-git() {
depends=('sdl2' 'libpng')
install -Dm755 "$srcdir/$_pkgbase/build/bin/citra" "$pkgdir/usr/bin/citra"
}
package_citra-qt-git() {
depends=('qt5-base' 'sdl2' 'shared-mime-info' 'desktop-file-utils')
optdepends=('libxkbcommon-x11: for X11 support'
'qt5-wayland: for Wayland support')
cd "$srcdir/$_pkgbase/build"
make DESTDIR="$pkgdir/" install
rm "$pkgdir/usr/bin/citra"
}
|