blob: aa5c60b0aade7d75abdf3c0e774391753912537e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
# Contributor: ceri
_pkgbase='citra'
pkgbase="$_pkgbase-git"
pkgname=("$_pkgbase-git" "$_pkgbase-qt-git")
pkgver=r4916.e634b757
pkgrel=1
pkgdesc="An experimental open-source Nintendo 3DS emulator/debugger"
arch=('i686' 'x86_64')
url="https://github.com/citra-emu/citra/"
license=('GPL2')
makedepends=('git' 'cmake' 'sdl2' 'qt5-base' 'shared-mime-info' 'desktop-file-utils')
source=("$_pkgbase::git+https://github.com/citra-emu/citra"
'git+https://github.com/citra-emu/ext-boost'
'git+https://github.com/svn2github/inih'
'git+https://github.com/neobrain/nihstro'
'git+https://github.com/citra-emu/ext-soundtouch'
'git+https://github.com/philsquared/Catch'
'git+https://github.com/MerryMage/dynarmic'
'git+https://github.com/fmtlib/fmt'
'git+https://github.com/herumi/xbyak'
'git+https://github.com/whoshuu/cpr'
'git+https://github.com/lsalzman/enet'
'git+https://github.com/nlohmann/json')
md5sums=('SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP')
pkgver() {
cd "$srcdir/$_pkgbase"
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgbase"
mkdir -p build
git submodule init
git config submodule.boost.url "$srcdir/ext-boost"
git config submodule.inih.url "$srcdir/inih"
git config submodule.nihstro.url "$srcdir/nihstro"
git config submodule.soundtouch.url "$srcdir/ext-soundtouch"
git config submodule.catch.url "$srcdir/Catch"
git config submodule.dynarmic.url "$srcdir/dynarmic"
git config submodule.cpr.url "$srcdir/cpr"
git config submodule.enet.url "$srcdir/enet"
git config submodule.json.url "$srcdir/json"
git submodule update
cd externals/dynarmic
git config submodule.externals/fmt.url "$srcdir/fmt"
git config submodule.externals/xbyak.url "$srcdir/xbyak"
git submodule update
}
build() {
cd "$srcdir/$_pkgbase/build"
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DUSE_SYSTEM_CURL=ON
make
}
check() {
cd "$srcdir/$_pkgbase/build"
make test
}
package_citra-git() {
depends=('sdl2' 'libpng')
install -Dm755 "$srcdir/$_pkgbase/build/src/citra/citra" "$pkgdir/usr/bin/$_pkgbase"
}
package_citra-qt-git() {
depends=('qt5-base' 'sdl2' 'shared-mime-info' 'desktop-file-utils')
optdepends=('libxkbcommon-x11: for X11 support'
'qt5-wayland: for Wayland support')
cd "$srcdir/$_pkgbase/build"
make DESTDIR="$pkgdir/" install
rm "$pkgdir/usr/bin/$_pkgbase"
}
|