blob: 95b095947be3ad3b7ee53168881a9cab5fb0b79b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Kevin MacMartin <prurigro@gmail.com>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: openfbt
# Contributor: Werecat
# Contributor: Xyne
_pkgname=cjdns
pkgname=$_pkgname-git
pkgver=22.r7.g2faa4c83
pkgrel=1
pkgdesc='A routing engine designed for security, scalability, speed and ease of use'
url='https://github.com/cjdelisle/cjdns'
license=('GPL3')
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
options=('!distcc' '!strip' '!buildflags')
depends=('bash')
makedepends=('cargo' 'git' 'nodejs' 'python' 'binutils' 'llvm')
optdepends=(
'cjdnsify: allows you to run some programs bound to your cjdns address'
'cjdns-git-sysvinit: support for sysvinit (rc.d)'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+$url#branch=master")
sha512sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --tags | sed 's|^[^-]*-v||;s|-|.r|;s|-|.|g'
}
build() {
cd $_pkgname
CJDNS_RELEASE_VERSION="${pkgver}" ./do
}
package() {
cd $_pkgname
install -Dm755 cjdroute "$pkgdir/usr/bin/cjdroute"
install -Dm755 contrib/sh/run-cjdroute.sh "$pkgdir/usr/bin/run-cjdroute"
install -Dm644 contrib/systemd/$_pkgname.service "$pkgdir/usr/lib/systemd/system/$_pkgname.service"
install -Dm644 contrib/systemd/$_pkgname-resume.service "$pkgdir/usr/lib/systemd/system/$_pkgname-resume.service"
install -Dm644 doc/man/cjdroute.conf.5 "$pkgdir/usr/share/man/man5/cjdroute.conf.5"
}
|