blob: 8f61bdd116fdf1a5b67bc6115ea76500b49124d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Tasos Sahanidis <aur@tasossah.com>
# Contributor: makz <contact+aur@makz.me>
# Contributor: Light2Yellow <oleksii.vilchanskyi@gmail.com>
pkgname=ckb-next-git
pkgver=0.6.2.r70.g02c2f2df
pkgrel=1
epoch=1
pkgdesc="Corsair Keyboard and Mouse Input Driver, git master branch"
arch=('i686' 'pentium4' 'x86_64')
url="https://github.com/ckb-next/ckb-next"
license=('GPL2')
depends=('qt6-base' 'hicolor-icon-theme' 'quazip-qt6' 'qt6-tools' 'qt6-wayland' 'libxcb' 'xcb-util-wm' 'python3' 'python-pyqt6' 'wayland-protocols')
makedepends=('git' 'cmake')
optdepends=('libpulse')
conflicts=('ckb-git' 'ckb-git-latest' 'ckb-next')
provides=('ckb-next')
install=ckb-next-git.install
source=('ckb-next-git::git+https://github.com/ckb-next/ckb-next.git'
'AUR-wrapper::git+https://github.com/ckb-next/AUR-wrapper.git')
sha256sums=('SKIP' 'SKIP')
pkgver() {
cd "$srcdir/${pkgname%-VCS}"
# based only on tags, always has long version as it's a rolling release
# discards v, replaces dashes with dots
git describe --tags --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/${pkgname%-VCS}"
cmake -H. -Bbuild \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_BUILD_TYPE="Release" \
-DCMAKE_INSTALL_LIBDIR="lib" \
-DCMAKE_INSTALL_LIBEXECDIR="lib" \
-DDISABLE_UPDATER=1 \
-DUDEV_RULE_DIRECTORY="/usr/lib/udev/rules.d" \
-DFORCE_INIT_SYSTEM="systemd"
cmake --build build --target all
}
package() {
cd "$srcdir/${pkgname%-VCS}"
DESTDIR="$pkgdir" cmake --build build --target install
# Rename the real binary and add the wrapper
mv "$pkgdir/usr/bin/ckb-next" "$pkgdir/usr/bin/ckb-next.real"
cd "$srcdir/AUR-wrapper"
install -Dm755 AUR_wrapper.py "$pkgdir/usr/bin/ckb-next"
}
|