blob: 141482bf342a59fe588e0781d8a5eab99ca23202 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Chris Severance aur.severach aATt spamgourmet dott com
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: Krzysztof Wloch <wloszekk@gmail.com>
# Contributor: demonicmaniac <stormtrooperofdeath@gmx.net>
set -u
pkgname='ckmame'
pkgver='1.0'
pkgrel='1'
pkgdesc='check ROM sets for MAME'
arch=('i686' 'x86_64')
url='https://www.nih.at/ckmame/'
license=('custom')
depends=('zlib' 'libxml2' 'libzip' 'sqlite3')
makedepends=('cmake')
checkdepends=('perl')
#_verwatch=("${url}" '.*Current version: \([0-9\.]\+\).*' 'f')
_verwatch=("${url}" "${pkgname}-\([0-9\.]\+\)\.tar\.xz" 'l')
_srcdir="${pkgname}-${pkgver}/build"
source=("https://nih.at/ckmame/${pkgname}-${pkgver}.tar.xz")
sha256sums=('efb294ec9276791c74345187d7e180fc214dbab84694ea26530179e7d4686e55')
build() {
set -u
if [ ! -d "${_srcdir}" ]; then
mkdir -p "${_srcdir}"
cd "${_srcdir}"
cmake .. -DCMAKE_INSTALL_PREFIX='/usr' -DDOCUMENTATION_FORMAT='man'
cd "${srcdir}"
fi
cd "${_srcdir}"
make VERBOSE=1
set +u
}
check() {
set -u
cd "${_srcdir}"
make test
set +u
}
package() {
set -u
cd "${_srcdir}"
make DESTDIR="${pkgdir}" install
cd ..
# Install a license file
install -Dm644 'LICENSE' -t "${pkgdir}/usr/share/licenses/${pkgname}"
set +u
}
set +u
|