blob: b2d6040963adffe373470fa6713a16fa0a2678f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=cl-3bmd
_pkgname="${pkgname#cl-}"
pkgver=r106.g4e08d82
pkgrel=1
pkgdesc='Markdown processor in Common Lisp using Esrap parser'
arch=('any')
url='https://github.com/3b/3bmd'
license=('MIT')
depends=(
'common-lisp'
'cl-asdf'
'cl-split-sequence'
'cl-esrap'
'cl-alexandria'
'cl-colorize'
'python-pygments'
)
makedepends=('git')
checkdepends=('sbcl' 'cl-fiasco')
_commit='4e08d82d7c8fb1b8fc708c87f4d9d13a1ab490cb'
source=(
"$pkgname::git+$url#commit=$_commit"
'run-tests.lisp'
)
b2sums=('SKIP'
'0438150ad0f16fa0c074e7b32e5cb411274da81ff715a3062abd6cb01f47f9fcc2ac94fe5e69837f8737977112683453e59cf0c0c1708a438095075516362d45')
pkgver() {
cd "$pkgname"
printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
check() {
cd "$pkgname"
sbcl --script ../run-tests.lisp
}
package() {
cd "$pkgname"
# create directories
install -vd \
"$pkgdir/usr/share/common-lisp/source/$_pkgname" \
"$pkgdir/usr/share/common-lisp/systems"
# library
install -vDm644 -t "$pkgdir/usr/share/common-lisp/source/$_pkgname" ./*.{lisp,asd,py}
pushd "$pkgdir/usr/share/common-lisp/systems"
ln -s "../source/$_pkgname/$_pkgname.asd" .
popd
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|