blob: 0d811715b3112bc8a6a9cfb22dfa5bf67f940684 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=cl-iterate
_pkgname="${pkgname#cl-}"
pkgver=1.5.3.r12.gea90d81
pkgrel=1
pkgdesc='An iteration construct for Common Lisp'
arch=('any')
url='https://iterate.common-lisp.dev'
license=('MIT')
depends=('common-lisp' 'cl-asdf')
makedepends=('git')
checkdepends=('sbcl' 'cl-rt')
_commit='ea90d8188703cd4c66123a39d4d604f2bb03e96d'
source=(
"$pkgname::git+https://gitlab.common-lisp.net/iterate/iterate.git#commit=$_commit"
'run-tests.lisp'
)
b2sums=('SKIP'
'19e7e1dae5906b3f9a2fa1ca4a5ca8f2c678bf2a681a07910f1cd9340628886a4de05c44f0d5b1a12436cae39a7fe1b11a64e4d83ea3c0ea62532fa58a67db13')
pkgver() {
cd "$pkgname"
git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
}
prepare() {
cd "$pkgname"
sed -n '/;;; Copyright/,/;; SOFTWARE/p' iterate-test.lisp | \
sed -r 's/^:::?//' > LICENSE-TESTS
sed -n '/ITERATE, An Iteration Macro/,/;;; SOFTWARE/p' iterate.lisp | \
sed -r 's/^:::?//' > LICENSE
}
check() {
cd "$pkgname"
sbcl --script ../run-tests.lisp
}
package() {
cd "$pkgname"
# create directories
install -vd \
"$pkgdir/usr/share/common-lisp/source/$_pkgname" \
"$pkgdir/usr/share/common-lisp/systems"
# library
install -vDm644 -t "$pkgdir/usr/share/common-lisp/source/$_pkgname" ./*.{lisp,asd}
pushd "$pkgdir/usr/share/common-lisp/systems"
ln -s "../source/$_pkgname/$_pkgname.asd" .
popd
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE*
}
|