blob: cd414a15dab6941d0c8cb416c0b607f020828e17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: AzureZeng <weedycn at outlook.com>
# Contributor: Shiroko <hhx.xxm at gmail.com>
# Contributor: Johnpoint <me at lvcshu.com>
pkgname=clash-for-windows-bin
pkgver=0.20.32
pkgrel=1
pkgdesc="A Windows/macOS/Linux GUI based on Clash and Electron."
arch=("x86_64" "aarch64")
url="https://github.com/Fndroid/clash_for_windows_pkg"
# logo_url="https://raw.githubusercontent.com/Dreamacro/clash/master/docs/logo.png"
logo_url="https://cdn.jsdelivr.net/gh/Dreamacro/clash@master/docs/logo.png"
install=clash-for-windows-bin.install
options=(!strip)
depends=('libxss' 'gtk3')
optdepends=(
'nftables: TUN mode required.'
'iproute2: TUN mode required.'
)
source=(
"clash.png::${logo_url}"
"clash-for-windows.desktop"
"cfw"
)
source_x86_64=(
"${pkgname}-${pkgver}-x86_64-linux.tar.gz::${url}/releases/download/${pkgver}/Clash.for.Windows-${pkgver}-x64-linux.tar.gz"
)
source_aarch64=(
"${pkgname}-${pkgver}-aarch64-linux.tar.gz::${url}/releases/download/${pkgver}/Clash.for.Windows-${pkgver}-arm64-linux.tar.gz"
)
sha256sums=('0d48a2ea1ee05ad4579b6e6996889548fa8a61a5ff6c85a32f7622cddfcb5782'
'd541a05f491ad5be9c90e0e8780757d5bc0a9199a7dce90bf451e2154f87ba70'
'd2e4a78f2360b271f7c7e803e84707a71a8a386ccaf95c2bb0b5fa263b43d318')
sha256sums_x86_64=('eca0825f05025b732dcab4801d10a5b3a5818f7aaefa755a69480be35cc78b75')
sha256sums_aarch64=('c59d94092a6fa2c96b1160075a639b933edb0b1e1298b0efbbb9d3981204ccc4')
package() {
local parch=$(echo ${CARCH} | sed "s/x86_64/x64/;s/aarch64/arm64/")
cd "Clash for Windows-${pkgver}-${parch}-linux"
echo "Packaging application files. Please wait."
install -d "${pkgdir}/opt/${pkgname}"
cp -r ./* "${pkgdir}/opt/${pkgname}"
install -Dm 755 ../cfw ${pkgdir}/usr/bin/cfw
install -Dm 644 ../clash.png ${pkgdir}/usr/share/pixmaps/clash.png
install -Dm 644 ../clash-for-windows.desktop ${pkgdir}/usr/share/applications/clash-for-windows.desktop
sed -e "s/VERSION_PLACEHOLDER/${pkgver}/g" -i ${pkgdir}/usr/share/applications/clash-for-windows.desktop
}
|