blob: b7cea2f6f81bb1ae7e14588d818432f8477f70c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: kiri@vern.cc
# Contributor: sukanka<su975853527 AT gmail dot com>
pkgname=clash-verge
pkgver=1.5.11
pkgrel=1
pkgdesc="A Clash Meta GUI based on Tauri, Continuation of Clash Verge"
arch=('x86_64' 'aarch64')
url="https://github.com/clash-verge-rev/clash-verge-rev"
license=('GPL-3.0-or-later')
depends=('cairo'
'clash-geoip'
'clash-meta'
'gcc-libs'
'gdk-pixbuf2'
'glib2'
'glibc'
'gtk3'
'hicolor-icon-theme'
'libayatana-appindicator'
'libsoup'
'openssl'
'webkit2gtk')
makedepends=('cargo-tauri'
'jq'
'moreutils'
'pnpm'
'rust')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
"${pkgname}.desktop"
)
sha512sums=('3d5fba3621a2a5bd2adedfd63189caf0d67971a3ba5e413279075ac0573535b13721d5f861c2de58faeb7706f62764aee9efd2ec6088e8b3fa582ffa491cda63'
'2066dacf2e5e0135e6403cbfb825efcdf08bbcdc781407e6bb1fbb85143817b2b1abef641d20390ff7e5b3e91a509933e9eb17a64f9de7671445ac6d5363a44a')
options=(!lto)
prepare() {
mv ${pkgname}-rev-${pkgver} ${pkgname}-${pkgver}
cd $srcdir/${pkgname}-${pkgver}
install -d src-tauri/sidecar
install -d src-tauri/resources
# empty files as placeholders
touch src-tauri/sidecar/clash{,-meta-alpha,-meta}-${CARCH}-unknown-linux-gnu
touch src-tauri/resources/Country.mmdb
touch src-tauri/resources/geo{ip,site}.dat
jq 'del(.scripts.prepare)' package.json | sponge package.json
cd src-tauri
# only build the excutable
jq '.tauri.bundle.active = false' tauri.conf.json | sponge tauri.conf.json
}
build() {
cd $srcdir/${pkgname}-${pkgver}
# export HOME=$srcdir
pnpm install
pnpm run check
cargo-tauri build
}
package() {
cd $srcdir/${pkgname}-${pkgver}
install -Dm755 src-tauri/target/release/${pkgname} -t ${pkgdir}/usr/bin
install -d ${pkgdir}/usr/lib/${pkgname}/resources
ln -sf /etc/clash/Country.mmdb -t ${pkgdir}/usr/lib/${pkgname}/resources
install -Dm644 src/assets/image/logo.bak.svg ${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg
install -Dm644 ${srcdir}/${pkgname}.desktop -t ${pkgdir}/usr/share/applications
}
|