blob: ab12594dc397352325d6b97931c259ad50565c6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Maintainer: Christian Hesse <mail@eworm.de>
pkgname=claws-mail-git
pkgver=3.12.0.r1.g3bedb72
pkgrel=1
pkgdesc='A GTK+ based e-mail client - git checkout'
arch=('i686' 'x86_64')
license=('GPL3')
url="http://www.claws-mail.org/"
depends=('gtk2' 'gnutls' 'startup-notification' 'enchant' 'gpgme' 'libetpan' 'compface'
'libsm' 'dbus-glib' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('git' 'spamassassin' 'bogofilter' 'valgrind'
# dependencies for plugins
'libsoup' 'libgdata' 'webkitgtk2' 'libnotify' 'libcanberra' 'poppler-glib' 'pygtk')
#'libchamplain' needed for geolocation plugin, disabled for now
# most time it's not compatible with current gnome releases
optdepends=('python2: needed for some tools and python plugin'
'perl: needed for some tools and perl plugin'
'spamassassin: adds support for spamfiltering'
'bogofilter: adds support for spamfiltering'
'libnotify: for notification plugin'
'libcanberra: for notification plugin'
'dbus: for notification plugin'
'expat: for rssyl plugin'
'libxml2: for fancy html viewer and gdata plugins'
'curl: for fancy html viewer, vcalendar, rssyl and spamreport plugins'
'libarchive: for archive plugin and various other plugins'
'libytnef: for tnef_parse plugin'
'webkitgtk2: for the fancy webkit html plugin'
'libsoup: for the fancy webkit html plugin'
'libgdata: for gdata plugin'
'poppler-glib: for pdf viewer plugin'
'ghostscript: for pdf viewer plugin')
replaces=('sylpheed-claws' 'claws-mail-extra-plugins')
conflicts=('claws-mail-extra-plugins' 'claws-mail')
provides=('claws' 'claws-mail')
install=claws-mail.install
source=('claws-mail::git://git.claws-mail.org/claws.git'
'http://www.eworm.de/download/linux/claws-timestamp.patch'
'http://www.eworm.de/download/linux/claws-git-version.patch')
pkgver() {
cd claws-mail/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
echo "$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG}).r$(git rev-list --count ${GITTAG}..).g$(git log -1 --format="%h")"
else
echo "0.r$(git rev-list --count master).g$(git log -1 --format="%h")"
fi
}
prepare() {
cd claws-mail/
# show timestamp in about dialog
patch -Np1 < ${srcdir}/claws-timestamp.patch
git update-index --assume-unchanged src/gtk/about.c
# change length of git commit hash
patch -Np1 < ${srcdir}/claws-git-version.patch
git update-index --assume-unchanged configure.ac
# fixes for python2
sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py
git update-index --assume-unchanged tools/*.py
}
build() {
cd claws-mail/
# run autogen without options - it runs ./configure for us, but we need to fix python first
NOCONFIGURE=1 ./autogen.sh
# fixes for python2
export PYTHON="/usr/bin/python2"
sed -i 's:python -c:python2 -c:g' configure
# add --enable-new-addrbook to the options to use the new address book
# do not forget to add claws-contacts to the dependencies then
./configure --disable-maintainer-mode \
--prefix=/usr \
--disable-static \
--enable-silent-rules \
--disable-jpilot \
--enable-enchant \
--enable-gnutls \
--enable-ldap \
--enable-crash-dialog \
--enable-pgpmime-plugin \
--enable-spamassassin-plugin \
--enable-bogofilter-plugin \
#--help
make
# build extra tools
cd tools/
make
}
package() {
cd claws-mail/
make DESTDIR="${pkgdir}" install
# install extra tools
# all executables and .conf files ; only top directory
cd tools
for FILE in $(find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf'); do
install -D -m0755 ${FILE} ${pkgdir}/usr/lib/claws-mail/tools/${FILE}
done
}
sha256sums=('SKIP'
'bbf29f10602a74d73f1a30d791ae49c3b1d5abf20c48db0f4c81b0dca7bc0078'
'd377a7a6278b84152cbb8095461223829c3a21e2ca2f35aa8862c058540b61d5')
|