blob: 4b47c3846734e5dc370d7b02565bfe7db1598ad8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Mikhail f. Shiryaev <mr dot felixoid at gmail dot com>
pkgname=clickhouse-lts
pkgver=22.8.13.20
pkgrel=1
pkgdesc='An open-source column-oriented database management system that allows generating analytical data reports in real time. LTS version'
arch=('x86_64' 'aarch64')
url='https://clickhouse.com'
license=('Apache')
depends=('tzdata' 'libcap')
provides=(clickhouse)
conflicts=(clickhouse)
_source_prefix='https://packages.clickhouse.com/deb/pool/main/c/clickhouse'
source_x86_64=(
"${_source_prefix}/clickhouse-client_${pkgver}_amd64.deb"
"${_source_prefix}/clickhouse-common-static_${pkgver}_amd64.deb"
"${_source_prefix}/clickhouse-server_${pkgver}_amd64.deb"
)
source_aarch64=(
"${_source_prefix}/clickhouse-client_${pkgver}_arm64.deb"
"${_source_prefix}/clickhouse-common-static_${pkgver}_arm64.deb"
"${_source_prefix}/clickhouse-server_${pkgver}_arm64.deb"
)
# for CARCH in x86_64 aarch64; do;
# pkgver=$(grep '^pkgver=' PKGBUILD | cut -f2 -d=);
# [ "$CARCH" == aarch64 ] && arch=arm64 || arch=amd64;
# CARCH=$CARCH makepkg --verifysource --nobuild --noextract;
# sha256sum clickhouse*"${pkgver}_${arch}.deb" | cut -f1 -d' ';
# done
sha256sums_x86_64=(
5b83f8b001665b0dfccb101d505c10c2db62a29d861bfa0300318bbfcb9c23b5
aac4f792dcf80ec68698ca7e8433b3f5c36bc1396f430c4e73837226631bcd32
9029ba9e428f9c624d6518ba0c1090606881448df208f7ffd9a2751a4dd368cf
)
sha256sums_aarch64=(
5fe7ff17d6952b852a1e6127961ab2e0192f5484c70858afe800e7b69c40e726
1e9eb599dfaad5b242717f08fc8b3b4a7e23c7a385ba939611d218218d4005d6
a8ab96b6f7073ba0b564d77f5aa34bb9702d5bd1db1e2d62d65f75e4b3cd0ac6
)
_noextract_x86_64=(
clickhouse-client_"${pkgver}"_amd64.deb
clickhouse-common-static_"${pkgver}"_amd64.deb
clickhouse-server_"${pkgver}"_amd64.deb
)
_noextract_aarch64=(
clickhouse-client_"${pkgver}"_arm64.deb
clickhouse-common-static_"${pkgver}"_arm64.deb
clickhouse-server_"${pkgver}"_arm64.deb
)
noextract=(
"${_noextract_x86_64[@]}"
"${_noextract_aarch64[@]}"
)
install=$pkgname.install
backup=(
'etc/clickhouse-client/config.xml'
'etc/clickhouse-server/config.xml'
'etc/clickhouse-server/users.xml'
)
package() {
debs="_noextract_${CARCH}[@]"
for deb in "${!debs}"; do
bsdtar -xf "$deb"
tar xf data.tar.gz -C "${pkgdir}"
done
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
mv "${pkgdir}/lib" "${pkgdir}/usr/lib"
mv "${pkgdir}/usr/share/doc/clickhouse-server/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/"
rm -rf "${pkgdir}/etc/cron.d" \
"${pkgdir}/etc/init.d" \
"${pkgdir}/etc/security" \
"${pkgdir}/etc/systemd" \
"${pkgdir}/usr/share/doc"
}
# vim:set ts=2 sw=2 et:
|