blob: cf53ee67fc03c3515f67a48d2311901296c04cbf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Mark Wagie <mark dot wagie at tutantota dot com>
# Contributor: Federico Di Pierro <nierro92@gmail.com>
pkgname=clightd
pkgver=5.4
pkgrel=2
pkgdesc="Bus interface to change screen brightness and capture frames from webcam."
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/FedeDP/Clightd"
license=('GPL')
depends=('systemd-libs>=237' 'linux-api-headers' 'libx11' 'libxrandr' 'libxext' 'polkit'
'ddcutil>=0.9.5' 'libmodule>=5.0.0' 'libjpeg-turbo' 'libusb' 'libdrm' 'wayland')
makedepends=('git' 'cmake')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('454e390c91a7f3ee8e74b1dc40d78ca4ade62d83546f0e298cdad1c919e43302')
build() {
cmake -B build -S Clightd-$pkgver \
-G "Unix Makefiles" \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBEXECDIR=lib/"$pkgname" \
-DENABLE_DDC=1 \
-DENABLE_GAMMA=1 \
-DENABLE_DPMS=1 \
-DENABLE_SCREEN=1 \
-DENABLE_YOCTOLIGHT=1 \
-Wno-dev
make -C build
}
package() {
make -C build DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/lib/systemd/system"
mv "$pkgdir/etc/systemd/system/$pkgname.service" "$pkgdir/usr/lib/systemd/system"
rm -rf "$pkgdir/etc/systemd"
}
|