blob: 6d0fd9342369f239ced18b51060ce978ac9a054c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=clipto-bin
pkgver=4.0.3
pkgrel=1
pkgdesc="Effortless, super fast and flexible notes taking app and clipboard manager."
arch=('x86_64')
url="https://clipto.pro"
license=('custom')
depends=('electron')
optdepends=('libnotify: for desktop notifications'
'libappindicator-gtk3: for tray icon')
provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}" "${pkgname%-bin}.pro")
replaces=("${pkgname%-bin}.pro")
source=("https://github.com/clipto-pro/Desktop/releases/download/v$pkgver/${pkgname%-bin}-$pkgver.AppImage"
"${pkgname%-bin}")
sha256sums=('059aa833a660ad4e27d62100300436cbfccf82c6262106a32704f6640a7f1eb3'
'9a741f1a1760de706698cb1576e3bb08846876c359aedd5d8854e69d913f0635')
prepare() {
chmod +x "${pkgname%-bin}-$pkgver.AppImage"
./"${pkgname%-bin}-$pkgver.AppImage" --appimage-extract
sed -i 's|Exec=AppRun|Exec=clipto|g' "squashfs-root/${pkgname%-bin}.desktop"
}
package() {
cd "$srcdir/squashfs-root"
find {locales,resources,usr/share/icons}/ -type d -exec chmod 755 {} +
install -d "$pkgdir/usr/lib/${pkgname%-bin}"
cp -r resources "$pkgdir/usr/lib/${pkgname%-bin}"
install -Dm755 "$srcdir/${pkgname%-bin}" -t "$pkgdir/usr/bin"
install -Dm644 "${pkgname%-bin}.desktop" -t "$pkgdir/usr/share/applications"
install -d "$pkgdir/usr/share/icons"
cp -r usr/share/icons/hicolor "$pkgdir/usr/share/icons"
}
|