blob: c9fd3f516a4bff1b8e0ead10eab9a8e68b4928e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=cloudflared
pkgver=2021.1.5
pkgrel=1
pkgdesc="Argo Tunnel client"
arch=(x86_64 armv7h aarch64)
url="https://github.com/cloudflare/cloudflared"
license=('custom:cloudflared')
depends=(glibc)
makedepends=(go)
conflicts=(cloudflared-bin)
backup=("etc/$pkgname/config.yml")
source=("$pkgname-$pkgver.tar.gz::https://github.com/cloudflare/cloudflared/archive/$pkgver.tar.gz"
"config.yml"
"$pkgname.service"
"sysusers.d.conf"
"tmpfiles.d.conf")
sha512sums=('bd109e2384d6fc779706d410bc4ce51003006affbb497869ab265807de8fa599d6825a062339f767fea366408edbb804da792cfee1fbf1ab9ab2e114153f774a'
'52a8e1a71b7195047ea490ade1caae8f82c7c332d9473611853b6cc21c31eb4403a94b66e9efc800faa4a1d3c0d8b5ad01d60896728161eeb4bf2a69ac58b95a'
'a3586fe91989e3d5e830eb824c2aa9d60387ada5351b3aee5f132342882403880b1150ec77b2cea6e231e452dbf9ed86e3fe04d736143eb2c2b7c40f8d996051'
'019e8bf95390d8f4815cf6118d419dba677967a22d9e68c245c71b32b198f188756e213ccada3f00b44a11b1486ef08780702ea0226086fc7e79e6c4466a26ae'
'6454925c07fd2ea737ac88d2275e5ca55debcdd675f47f7f2a640357591547b96631993cfb210bc31efe793536173b8d878e381fc18e7f6e80262cde81db0ab9')
build() {
cd "$pkgname-$pkgver"
go build -v \
-buildmode=pie \
-trimpath \
-mod=vendor \
-modcacherw \
-ldflags "-extldflags $LDFLAGS -X "main.Version=${pkgver}" -X "main.BuildTime="$(date --iso-8601=seconds --utc)""" \
github.com/cloudflare/cloudflared/cmd/cloudflared
}
package() {
# binary
install -Dm755 -t "$pkgdir/usr/bin" "$pkgname-$pkgver/$pkgname"
# license
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgname-$pkgver/LICENSE"
# systemd files
install -Dm644 -t "$pkgdir/usr/lib/systemd/system" "$pkgname.service"
install -Dm644 sysusers.d.conf "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
install -Dm644 tmpfiles.d.conf "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
# config
install -Dm644 -t "$pkgdir/etc/$pkgname" config.yml
}
# vim:set ts=2 sw=2 et:
|