blob: 512ade2489c45c914de55ca4afb25272a134c695 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Hao Long <aur@esd.cc>
pkgname=cloudflared-bin
pkgver=2021.6.0
pkgrel=1
pkgdesc="An Argo Tunnel client which proxies any local webserver through the Cloudflare network"
arch=("x86_64" "i686" "aarch64" "armv6h" "armv7h")
url="https://developers.cloudflare.com/argo-tunnel/"
_url="https://github.com/cloudflare/cloudflared"
license=("custom")
depends=("glibc")
provides=("cloudflared")
conflicts=("cloudflared")
source=("https://raw.githubusercontent.com/cloudflare/cloudflared/master/LICENSE"
"cloudflared.yml"
"cloudflared@.service"
"cloudflared-dns.service"
"sysusers.d")
source_x86_64=("${pkgname}-x86_64-${pkgver}::${_url}/releases/download/${pkgver}/cloudflared-linux-amd64")
source_i686=("${pkgname}-386-${pkgver}::${_url}/releases/download/${pkgver}/cloudflared-linux-386")
source_aarch64=("${pkgname}-aarch64-${pkgver}::${_url}/releases/download/${pkgver}/cloudflared-linux-arm64")
source_armv6h=("${pkgname}-armv6h-${pkgver}::${_url}/releases/download/${pkgver}/cloudflared-linux-armv6")
source_armv7h=("${pkgname}-armv7h-${pkgver}::${_url}/releases/download/${pkgver}/cloudflared-linux-armv6")
sha256sums=('6a486a0f6c00e87cce1caf0aa8db45ea9fefd0bf91d9be6fc44460160dc0dbda'
'e769786afdfbd486a4d7ca99495dbe955c25e41b5e012b722b018ca17f269dac'
'83234a52452dce5497dd04e27323b2f83c702d4435a2687d1be4f829451fb061'
'bc40e3f7e1b21b93a949a1b1c05639584943d9ce9cc7ccb96612688eeb9fd206'
'bfda935c07b8e49821ee13e19433b1ed475ebb651e3008a32950734afbaef813')
sha256sums_x86_64=('56f83406f8320727303c3c03dd0d3903decaea3731cf2a275d5c6e0cb0e627bd')
sha256sums_i686=('60035a06e009f251eaa77d5312ef3dc0518bbd8f3bb99965af06579310411b81')
sha256sums_aarch64=('e397e0115d7fb438c9991b778eff08569308b9aaeba47689a88eceb1caaa356c')
sha256sums_armv6h=('21f0aa9d67b96c14a56a1c3df3eba1c1dea62162417621795c8b14517daf8847')
sha256sums_armv7h=('21f0aa9d67b96c14a56a1c3df3eba1c1dea62162417621795c8b14517daf8847')
package() {
# Install License
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
# Install Binary
install -Dm755 cloudflared-bin-* ${pkgdir}/usr/bin/cloudflared
# Configuration File
install -Dm644 cloudflared.yml ${pkgdir}/etc/cloudflared/cloudflared.yml.example
install -Dm644 -t ${pkgdir}/usr/lib/systemd/system cloudflared{@,-dns}.service
# Post install
install -Dm644 sysusers.d ${pkgdir}/usr/lib/sysusers.d/cloudflared.conf
}
|