blob: 86d0c09a9e33d402d7d584de98f17456e50ed2e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=cmake
pkgver=3.30.2
pkgrel=1
pkgdesc='A cross-platform open-source make system'
arch=('x86_64')
url="https://www.cmake.org/"
license=('custom')
depends=(cppdap
curl
expat
gcc-libs
glibc
hicolor-icon-theme
jsoncpp
libarchive
libuv
ncurses
rhash
zlib)
makedepends=(emacs
git
nlohmann-json
python-sphinx
qt6-base)
optdepends=(
'make: for unix Makefile generator'
'ninja: for ninja generator'
'qt6-base: cmake-gui'
)
source=(git+https://gitlab.kitware.com/cmake/cmake#tag=v$pkgver?signed)
sha512sums=('f9d65bb348b48ec24eae1a42437aff60c875f0235906663dbf9c1d74363529b9ddd9745c337f8c2fa947e0ab60a7c1ef4beb884962552ea79af8d6f12b7d93a8')
validpgpkeys=(CBA23971357C2E6590D9EFD3EC8FEF3A7BFB4EDA) # Brad King <brad.king@kitware.com>
build() {
cd ${pkgname}
./bootstrap --prefix=/usr \
--mandir=/share/man \
--docdir=/share/doc/cmake \
--datadir=/share/cmake \
--sphinx-man \
--sphinx-html \
--system-libs \
--qt-gui \
--parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
make
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
rm -r "$pkgdir"/usr/share/doc/cmake/html/_sources
emacs -batch -f batch-byte-compile "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
install -Dm644 Copyright.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|