summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 74744cbd71b7a91bff39b06969828be704641f78 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=cmb
pkgbase=cmb
pkgver=1.4.1
pkgrel=1
pkgdesc="combinatorics utility"
url="https://fraubsd.org/cmb"
arch=('x86_64')
license=('BSD')
makedepends=('libcmb' 'awk')
depends=('openssl' 'libcmb')
source=("git+https://github.com/FrauBSD/pkgcenter")
sha256sums=('SKIP')

pkgver() {
  cd pkgcenter/depend/cmb
  awk 'match($$0, /\$Version: [^$]* \$/) {
         print substr($0, RSTART + 10, RLENGTH - 12);
         exit found=1;
       } END { exit !found }' cmb.c
}

prepare() {
  cd pkgcenter/depend/cmb
  ./configure --prefix /usr
}

build() {
  cd pkgcenter/depend/cmb
  make
}

package() {
  cd pkgcenter/depend/cmb

  # Disabled for now because DESTDIR isn't respected
  #DESTDIR="$pkgdir" make install

  install -dm755 "$pkgdir"/usr/bin
  install -m755 cmb "$pkgdir"/usr/bin/

  install -dm755 "$pkgdir"/usr/share/man/man1
  install -m444 cmb.1.gz "$pkgdir"/usr/share/man/man1/
}