PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

pkgname=cmdcreate-git
pkgver=r1617.ca1bc9e
pkgrel=2
pkgdesc="Easily create and manage your own custom commands"
arch=('x86_64' 'i686' 'aarch64')
url="https://github.com/owen-debiasio/cmdcreate"
license=('GPL-3.0-or-later')

depends=('less' 'git' 'curl')
makedepends=('cargo' 'git' 'zig' 'cargo-zigbuild')

conflicts=('cmdcreate')
provides=('cmdcreate')
source=("cmdcreate::git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd cmdcreate
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd cmdcreate
  rm -f .cargo/config.toml

  local _target="${CARCH}-unknown-linux-musl"
  rustup target add "$_target" || true
  cargo fetch --locked --target "$_target"
}

build() {
  cd cmdcreate

  local _target="${CARCH}-unknown-linux-musl"

  export CFLAGS="-O3 -pipe"
  export CXXFLAGS="-O3 -pipe"
  export LDFLAGS=""

  export RUSTFLAGS="-C target-feature=+crt-static -C link-arg=-fno-sanitize=all"
  export CRATE_CC_NO_DEFAULTS=true

  cargo zigbuild --release --frozen --target "$_target"
}

package() {
  cd cmdcreate

  local _target_dir="target/${CARCH}-unknown-linux-musl/release"

  install -Dm755 "$_target_dir/cmdcreate" "$pkgdir/usr/bin/cmdcreate"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}