PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

pkgname='cockroachdb-git'
pkgdesc='A Scalable, Geo-Replicated, Transactional Datastore'
pkgver=r17033.g0ba52ff84
pkgrel=1
license=('Apache')
url='https://github.com/cockroachdb/cockroach'
source=("${pkgname}::git+${url}")
sha512sums=('SKIP')
arch=('x86_64')
depends=('gcc-libs>=6.0')
makedepends=('go')
conflicts=('cockroachdb')
provides=('cockroachdb')


pkgver () {
	cd "${GOPATH}/src/github.com/cockroachdb/cockroach"
	(
		set -o pipefail
		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	) | sed 's/alpha\.//'
}

prepare () {
	export GOPATH="$(pwd)/go"
	rm -rf "${GOPATH}/src/github.com/cockroachdb/cockroach"
	mkdir -p "${GOPATH}/src/github.com/cockroachdb"
	mv "${pkgname}" "${GOPATH}/src/github.com/cockroachdb/cockroach"
}

build () {
	export GOPATH="$(pwd)/go"
	cd "${GOPATH}/src/github.com/cockroachdb/cockroach"

	# Do not use "make release", is the LDFLAGS added by the Makefile
	# result in linkage errors.
	make .bootstrap
	go build -v -i -o cockroach
}

package () {
	export GOPATH="$(pwd)/go"
	cd "${GOPATH}/src/github.com/cockroachdb/cockroach"
	install -Dm755 cockroach "${pkgdir}/usr/bin/cockroach"
}