blob: 8798371248c54f15ba4e8ac4e554f268d378821e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Michael Hansen <zrax0111 gmail com>
pkgname=visual-studio-code-oss
pkgdesc='Visual Studio Code for Linux, Open Source version'
pkgver=0.10.9
pkgrel=1
arch=('i686' 'x86_64')
url='https://code.visualstudio.com/'
license=('MIT')
makedepends=('npm' 'gulp' 'python2')
depends=('gtk2' 'gconf')
conflicts=('vscode-oss')
provides=('vscode-oss')
source=("https://github.com/Microsoft/vscode/archive/${pkgver}.tar.gz"
"${pkgname}.desktop"
'fix_super.patch'
'product_json.patch')
sha1sums=('94c6fa5db974d26e769e1f80a24f996424de7041'
'2039174831d5483050471d69e0765b684cbeeefe'
'd51635bd1e9568eb31224170b10d48154dcc2c8c'
'4a7f41876a016ef8d969fb81c7b1b4bc7b1e026b')
case "$CARCH" in
i686)
_vscode_arch=ia32
;;
x86_64)
_vscode_arch=x64
;;
*)
# Needed for mksrcinfo
_vscode_arch=DUMMY
;;
esac
prepare() {
cd "${srcdir}/vscode-${pkgver}"
patch -p1 -i "${srcdir}/fix_super.patch"
patch -p1 -i "${srcdir}/product_json.patch"
}
build() {
cd "${srcdir}/vscode-${pkgver}"
# npm 3.x flattens modules, which the package tasks can't handle yet
./scripts/npm.sh install 'npm@2'
export PATH="${srcdir}/vscode-${pkgver}/node_modules/.bin:$PATH"
./scripts/npm.sh install
gulp vscode-linux-${_vscode_arch}
}
package() {
install -m 0755 -d "${pkgdir}/opt/VSCode-OSS"
cp -r "${srcdir}/VSCode-linux-${_vscode_arch}"/* "${pkgdir}/opt/VSCode-OSS"
# Include symlink in system bin directory
install -m 0755 -d "${pkgdir}/usr/bin"
ln -s '/opt/VSCode-OSS/Code - OSS' "${pkgdir}/usr/bin/${pkgname}"
# Add .desktop file
install -D -m644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Install license file
install -D -m644 "${srcdir}/VSCode-linux-${_vscode_arch}/resources/app/LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|