blob: a034c6ad445c7f2deecd3a15d20c572370e0f27c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Michael Hansen <zrax0111 gmail com>
pkgname=visual-studio-code-oss
pkgdesc='Visual Studio Code for Linux, Open Source version'
pkgver=1.6.1
pkgrel=2
_commit=9e4e44c19e393803e2b05fe2323cf4ed7e36880e
arch=('i686' 'x86_64')
url='https://code.visualstudio.com/'
license=('MIT')
makedepends=('npm' 'nodejs>=6.8.0' 'gulp' 'python2')
depends=('gtk2' 'gconf' 'libnotify' 'libxss' 'libxtst' 'nss' 'alsa-lib')
conflicts=('vscode-oss')
provides=('vscode-oss')
source=("${pkgver}-${pkgrel}.tar.gz::https://github.com/Microsoft/vscode/archive/${_commit}.tar.gz"
"${pkgname}.desktop"
'product_json.patch'
'old-gulp-sourcemaps.patch')
sha1sums=('d2b827fbc7aa8b54343f6cda452fb74142e1993a'
'9c4176c4d99103736df6746ca174b5026bd57e6b'
'ba8febe936932080610d899fdb57294fc2f9f614'
'e614e05c4b591bbc2514c944bf43330d69102542')
case "$CARCH" in
i686)
_vscode_arch=ia32
;;
x86_64)
_vscode_arch=x64
;;
*)
# Needed for mksrcinfo
_vscode_arch=DUMMY
;;
esac
prepare() {
cd "${srcdir}/vscode-${_commit}"
patch -p1 -i "${srcdir}/product_json.patch"
_datestamp=$(date -u -Is | sed 's/\+00:00/Z/')
sed -e "s/@COMMIT@/$_commit/" -e "s/@DATE@/$_datestamp/" \
-i product.json
# 1.8.0 is pulled in by default, which is currently broken upstream
patch -p1 -i "${srcdir}/old-gulp-sourcemaps.patch"
}
build() {
cd "${srcdir}/vscode-${_commit}"
./scripts/npm.sh install
# The default memory limit is too low for current versions of node to
# successfully build vscode. This will set it to 2GB -- change it if
# this number still doesn't work for your system.
node --max_old_space_size=2048 /usr/bin/gulp vscode-linux-${_vscode_arch}
}
package() {
install -m 0755 -d "${pkgdir}/opt/VSCode-OSS"
cp -r "${srcdir}/VSCode-linux-${_vscode_arch}"/* "${pkgdir}/opt/VSCode-OSS"
# Include symlink in system bin directory
install -m 0755 -d "${pkgdir}/usr/bin"
ln -s '/opt/VSCode-OSS/code-oss' "${pkgdir}/usr/bin/${pkgname}"
# Add .desktop file
install -D -m644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Install license file
install -D -m644 "${srcdir}/VSCode-linux-${_vscode_arch}/resources/app/LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|