blob: 12ea9593d4cd5ff46feb3296c4b92b7b4643a067 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="code2prompt"
pkgver=4.2.0
pkgrel=1
pkgdesc="CLI tool to convert your codebase into a single LLM prompt"
arch=(
'x86_64'
)
url="https://code2prompt.dev"
_url="https://github.com/mufeedvh/${pkgname}"
license=(
'MIT'
)
depends=(
'gcc-libs'
'glibc'
'zlib'
)
makedepends=(
'cargo'
)
_pkgsrc="${pkgname}-${pkgver}"
source=(
# "${_pkgsrc}.tar.gz::${_url}/archive/refs/tags/v${pkgver}.tar.gz"
"https://static.crates.io/crates/${pkgname}/${_pkgsrc}.crate"
)
sha256sums=('e6b5b194027bfc72f356ecb5d80773bfbe558e5e786384123cf5bf12388cadd5')
_source() {
export CARGO_HOME="${srcdir}/.cargo"
export CARGO_TARGET_DIR=target
export RUSTUP_TOOLCHAIN=stable
}
prepare() {
_source
cd "${srcdir}/${_pkgsrc}"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
_source
export CFLAGS+=" -ffat-lto-objects"
cd "${srcdir}/${_pkgsrc}"
cargo build --frozen --release --all-features
}
check() {
_source
cd "${srcdir}/${_pkgsrc}"
cargo test --frozen --all-features
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
# install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|