blob: 9090f4c7eeafdd5ab02b073d0c22745e5e922388 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: jinzhongjia <mail@nvimer.org>
pkgname=codebase-memory-mcp
pkgver=0.9.0
pkgrel=1
pkgdesc="High-performance code intelligence MCP server with persistent knowledge graph"
arch=('x86_64' 'aarch64')
url="https://github.com/DeusData/codebase-memory-mcp"
license=('MIT')
depends=('glibc' 'gcc-libs' 'zlib')
optdepends=('git: git-history change-coupling analysis')
conflicts=("${pkgname}-bin" "${pkgname}-ui-bin" "${pkgname}-git")
options=('!lto' '!debug')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('05fd0963b4c7c7ecccfa12f50a4a33130ad90019a62c0fc13808a524a8f86abe')
build() {
cd "${pkgname}-${pkgver}"
# LIBGIT2 forced off: the HAVE_LIBGIT2 path uses git_allocator without
# including <git2/sys/alloc.h> and won't compile. Upstream release binaries
# are static/zero-dep with libgit2 off too; git history parsing falls back
# to `git log`. -Wno-error: upstream's -Werror trips on benign warnings
# under Arch's newer GCC. CBM_VERSION stamps the --version string.
make -j"$(nproc)" -f Makefile.cbm cbm \
CFLAGS_EXTRA="-DCBM_VERSION=\"\\\"${pkgver}\\\"\" -Wno-error" \
LIBGIT2_LIBS= LIBGIT2_CFLAGS= LIBGIT2_FLAGS=
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 build/c/codebase-memory-mcp "${pkgdir}/usr/bin/codebase-memory-mcp"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|