blob: 9aeae5098cd956cf7fa8ae4e6c07ff93f6194919 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Chris Severance aur.severach aATt spamgourmet dott com
# Contributor: Bill Pickett <pickett dot bill at gmail dot com>
# Contributor: Roman Konchits <admin at xan dot lt>
# Contributor: Hubert Maraszek <marach5 at gmail dot com>
# Contributor: schtroumpfette
set -u
pkgname='codeblocks-svn'
pkgver=20.03.r12286
pkgrel=1
pkgdesc='An open source and cross-platform C/C++ IDE'
arch=('i686' 'x86_64')
url='http://www.codeblocks.org'
license=('GPL')
depends=('wxgtk2' 'valgrind' 'bzip2' 'hicolor-icon-theme' 'gamin' 'hunspell' 'webkit2gtk')
makedepends=('boost' 'subversion' 'zip')
provides=("codeblocks=${pkgver}")
conflicts=('codeblocks' 'codeblocks-svn-noplugins')
#install="${pkgname}.install"
options=('!libtool')
source=('codeblocks-svn::svn://svn.code.sf.net/p/codeblocks/code/trunk')
sha256sums=('SKIP')
pkgver() {
set -u
cd 'codeblocks-svn'
local _ver="$(sed -n -e 's:^.\+ version \(.\+\)$:\1:p' 'README')" # $() trim trailing newline
local _rev="$(svnversion | tr -d '[A-z]')"
printf '%s.r%s' "${_ver}" "${_rev}"
set +u
}
build() {
set -u
cd 'codeblocks-svn'
if [ ! -s 'configure' ]; then # compatible with makepkg -e
./bootstrap
fi
if [ ! -s 'Makefile' ]; then
WX_CONFIG_PATH='/usr/bin/wx-config' \
./configure --prefix='/usr' --with-contrib-plugins='all'
fi
local _nproc="$(nproc)"; _nproc=$((_nproc>8?8:_nproc))
nice make -s -j"${_nproc}"
set +u
}
package() {
set -u
cd 'codeblocks-svn'
make DESTDIR="${pkgdir}" install
set +u
}
set +u
|