blob: e9df90cd570c48a668d64f60cf59903aa722ee4d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
# Contributor: Pyro Devil <p dot devil at gmail dot com>
pkgname=codelite-git
_gitname=codelite
pkgver=9.2.r172.g3cbec86
pkgrel=1
pkgdesc="Open-source, cross platform IDE for the C/C++ programming languages"
arch=('i686' 'x86_64')
url="http://www.codelite.org/"
license=('GPL')
install=codelite-git.install
makedepends=('pkgconfig' 'cmake' 'clang')
depends=(
'wxgtk'
'webkitgtk2'
'libedit'
'libssh'
'libmariadbclient'
'ncurses'
'xterm'
'curl'
'python2'
'clang'
'lldb'
'hunspell'
)
optdepends=(
'graphviz: callgraph visualization'
'clang: compiler'
'gcc: compiler'
'gdb: debugger'
'valgrind: debugger'
)
conflicts=('codelite' 'codelite-bin')
provides=('codelite')
source=(
git://github.com/eranif/codelite.git
http://repos.codelite.org/wxCrafterLibs/wxgui.zip
)
md5sums=(
'SKIP'
'093485fcae62073ca8d0ba6ff3a5cb69'
)
noextract=('wxgui.zip')
pkgver() {
cd "${srcdir}/${_gitname}"
git describe --tags --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_gitname}"
mkdir -p build
}
build() {
cd "${srcdir}/${_gitname}/build"
CXXFLAGS="${CXXFLAGS} -fno-devirtualize"
cmake -G "Unix Makefiles" -DCMAKE_BUILD_TYPE=Release \
-DENABLE_CLANG=1 -DENABLE_LLDB=1 -DWITH_MYSQL=1 \
-DCMAKE_INSTALL_LIBDIR=lib \
..
make
}
package() {
cd "${srcdir}/${_gitname}/build"
make -j1 DESTDIR="${pkgdir}" install
install -m 644 -D "${srcdir}/wxgui.zip" "${pkgdir}/usr/share/codelite/wxgui.zip"
install -m 644 -D "${srcdir}/${_gitname}/LICENSE" "${pkgdir}/usr/share/licenses/codelite/LICENSE"
}
|