summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: efc9a3ff5171d28e5e8d676f064e28d156ac4537 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Adrian Perez de Castro <aperez@igalia.com>
pkgdesc='WPE launcher and webapp container'
pkgname=cog
pkgver=0.4.0
pkgrel=2
url=https://github.com/Igalia/cog
arch=(i686 x86_64 aarch64 armv7l armv7h)
groups=(wpe)
conflicts=(cog-git)
depends=('wpewebkit>=2.26.0' 'wpebackend-fdo>=1.4.0')
makedepends=(cmake)
license=(custom:MIT)
source=("https://wpewebkit.org/releases/releases/${pkgname}-${pkgver}.tar.xz"
        "https://wpewebkit.org/releases/releases/${pkgname}-${pkgver}.tar.xz.asc")
validpgpkeys=('5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')
md5sums=('75a0838ee6c81bb8df1b254f525440a6' 'SKIP')
sha1sums=('284d2a641e6269b296057918602c8c94eb831527' 'SKIP')
sha256sums=('e9c13a51232434b7340a419b1e6f59c40c582cd80c8e60bd9ec7de16c904fc03' 'SKIP')

build () {
	cmake -H"${pkgname}-${pkgver}" -Bbuild \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBDIR=/usr/lib
	cmake --build build
}

package () {
	DESTDIR="${pkgdir}" cmake --build build --target install

	install -Dm644 "${pkgname}-${pkgver}/COPYING" \
		"${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}