PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

pkgbase=collab3
pkgname=("$pkgbase-standalone-bin" "$pkgbase-vst-bin")
pkgver=1.0.0
pkgrel=4
arch=('x86_64')
license=('EULA')
url="https://github.com/augustofilocamo/superOrgan"
depends=('alsa-lib' 'bzip2' 'brotli' 'freetype2' 'glibc' 'graphite' 'harfbuzz' 'krb5' 'libpng' 'libxau' 'libxext' 'libxcb' 'libx11' 'pcre2' 'zlib')
source=("https://github.com/augustofilocamo/superOrgan/releases/download/v${pkgver}/CollaB3-Installer-${pkgver}.sh"
		"collab3.png"
		"CollaB3.desktop")
sha256sums=('9e4c14c53ba17e9871147423016f6644f2ca366c1e8c7062e6f63a36127ed381'
			'8d29d2e7f50f504bd973b9abe0dbfdf4089a56caeecf309aa118d070f02d346b'
			'a4d78c36d22d66897e3e79bc1928e5573cd74965db1cfe1ee63024c554c0f1f6')

prepare() {
	# Extract Package
	sh "${srcdir}/CollaB3-Installer-${pkgver}.sh" --tar xvf
}

package_collab3-standalone-bin() {
	# Standalone App
	groups=('pro-audio')
	pkgdesc="CollaB3 Tone Wheel Organ (Standalone)"
	install -Dm755 "${srcdir}/CollaB3" "${pkgdir}/usr/bin/CollaB3"
	install -Dm644 "${srcdir}/collab3.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/collab3.png"
	install -Dm644 "${srcdir}/CollaB3.desktop" "${pkgdir}/usr/share/applications/CollaB3.desktop"
}

package_collab3-vst-bin() {
	# VST Plugin
	groups=('pro-audio' 'vst-plugins')
	pkgdesc="CollaB3 Tone Wheel Organ (VST)"
	install -Dm755 "${srcdir}/CollaB3.so" "${pkgdir}/usr/lib/vst/CollaB3.so"
}