blob: d3c41f7885c86e1e5c5902098359cda78bd25c91 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Former maintainer: John Jenkins <twodopeshaggy@gmail.com>
# Contributor: Mariusz Libera <mariusz.libera@gmail.com>
# Contributor: Juergen Graefe <jg72@gmx.de>
pkgname=colormake
pkgver=0.9.20140503
pkgrel=1
pkgdesc="Colorize the output of make"
arch=('any')
url="https://bre.klaki.net/programs/colormake/"
license=('GPL2')
depends=('perl' 'bash')
source=("https://github.com/pagekite/Colormake/archive/$pkgver.tar.gz")
sha256sums=('a3f9fae9a455ac96be1cce0371b28bda33a9af73b06fa8e4329aa2f693d68d22')
prepare() {
cd "Colormake-$pkgver"
# adjust scripts to colormake.pl path
sed -i 's#colormake.pl#/usr/share/colormake/colormake.pl#g' "colormake"
}
package() {
cd "Colormake-$pkgver"
# executables
install -dm755 "$pkgdir/usr/bin"
cp -r {clmake,clmake-short,colormake,colormake-short} "$pkgdir/usr/bin"
install -Dm755 "colormake.pl" "$pkgdir/usr/share/colormake/colormake.pl"
# man page
install -Dm644 "colormake.1" "$pkgdir/usr/share/man/man1/colormake.1"
# documentation
install -dm755 "$pkgdir/usr/share/doc/colormake"
install -m644 \
AUTHORS \
BUGS \
ChangeLog \
README \
"$pkgdir/usr/share/doc/colormake"
}
|