PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Christian Pfeiffer <cpfeiffer at live de>
# Contributor: Michael Straube <straubem gmx de>
# Contributor: xantares <xantares09 at hotmail dot com>

pkgname=combblas
pkgver=1.6.2
pkgrel=1
pkgdesc="Combinatorial BLAS Library"
arch=('x86_64')
url="http://gauss.cs.ucsb.edu/~aydin/CombBLAS/html/"
license=("MIT")
depends=('openmpi')
makedepends=('cmake')
_filename="CombBLAS_beta_16_2"
source=("http://gauss.cs.ucsb.edu/~aydin/CombBLAS_FILES/${_filename}.tgz")

sha512sums=('de63b6da77563cd1e074f44d6892c8d1dcb7aa9475f617b2de60239485e6dbd5965a305471f933fe175778a12fc6bb987a75f3631487b6461a382c5419b267aa')

prepare() {
  mkdir build
}

build() {
  cd build

  # Some tests are computationally heavy MPI stuff, so avoid them
  cmake "${srcdir}/${_filename}" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_INSTALL_RPATH=ON \
    -DBUILD_SHARED_LIBS=ON \
    -DBUILD_TESTING=OFF

  make
}

package() {
  cd build

  make DESTDIR="${pkgdir}" install

  # Remove OS X leftover files
  find "${pkgdir}" -name "*.DS_Store" -delete
  find "${pkgdir}" -name "._*" -delete

  install -Dm644 "${srcdir}/${_filename}/LICENSE" -t "${pkgdir}"/usr/share/licenses/$pkgname/
}