summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2db91d7e02b917368ac6b6ccd581c6198b69d323 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Fabien Dubosson <fabien.dubosson@gmail.com>
# Contributor: Adam Harvey <aharvey@sourcegraph.com>
pkgname=comby
pkgver=1.8.1
pkgrel=2
pkgdesc="A tool for structural code search and replace that supports ~every language."
arch=('x86_64')
url="https://comby.dev/"
license=('Apache')
depends=('pkgconf' 'pcre' 'glibc' 'libev' 'zlib' 'sqlite')
makedepends=('opam' 'dune' 'ocamlbuild')
source=("https://github.com/comby-tools/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('04d51cf742bbbf5e5fda064a710be44537fac49bff598d0e9762a3a799d666e2')

build() {
        cd "$srcdir/$pkgname-$pkgver"

        opam init -n
        eval $(opam env)

        opam update
        opam install . --deps-only -y

        make release
}

check() {
        cd "$srcdir/$pkgname-$pkgver"
        make test
}

package() {
        cd "$srcdir/$pkgname-$pkgver"

        DESTDIR="${pkgdir}" dune install --prefix "/usr"  --libdir "/usr/lib/ocaml"

        install -dm755 "${pkgdir}/usr/share/"
        mv "${pkgdir}/usr/doc" "${pkgdir}/usr/share/"
}