PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

# Maintainer: txtsd <auur.archlinux@ihavea.quest>
# Contributor: loathingkernel <loathingkernel _a_ gmail _d_ com>
# Contributor: RealStickman <mrc+aur _a_ frm01 _d_ net>

pkgname=comictagger-beta
pkgver=1.6.0_beta.2
_pkgver="${pkgver//_/-}"
pkgrel=1
pkgdesc='A multi-platform app for writing metadata to digital comics'
arch=(any)
url='https://github.com/comictagger/comictagger'
license=('Apache-2.0')
depends=(
  python
  python-appdirs
  python-beautifulsoup4
  python-comicfn2dict
  python-importlib-metadata
  python-isocodes
  python-natsort
  python-pathvalidate
  python-pillow
  python-py7zr
  python-pyicu
  python-pyqt5
  python-pyrate-limiter-2
  python-rapidfuzz
  python-rarfile
  python-requests
  python-settngs
  python-text2digits
  python-typing_extensions
  python-wordninja
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools-scm
  python-wheel
)
options=(!debug)
source=(git+${url}.git#tag=${_pkgver})
sha256sums=('ae52d0e848b9f1a8733d7f88c09d46fdfa59d3ee7837c4c7782a8f6fb97c14d7')

prepare() {
  cd comictagger

  # sed -e 's/RequestRate/Rate/g' -i tests/conftest.py
  # sed -e 's/RequestRate/Rate/g' -i comictalker/talkers/comicvine.py

  sed -e 's|/usr/local/share/comictagger/app.png|/usr/share/icons/comictagger.png|g' \
    -e 's|%%CTSCRIPT%% %F|/usr/bin/comictagger|g' \
    -i build-tools/ComicTagger.desktop
}

pkgver() {
  cd comictagger

  git describe --tags | sed 's/-/_/g'
}

build() {
  cd comictagger

  python -m build --wheel --no-isolation
}

package() {
  cd comictagger

  python -m installer --destdir="${pkgdir}" dist/*.whl

  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
  rm -rf "${pkgdir}/usr/lib/python${python_version}/site-packages/tests/"

  sed -e 's|/usr/local/share/comictagger/app.png|/usr/share/icons/comictagger.png|g' \
    -e 's|%%CTSCRIPT%% %F|/usr/bin/comictagger|g' \
    -i build-tools/ComicTagger.desktop

  install -Dm644 build-tools/ComicTagger.desktop "${pkgdir}"/usr/share/applications/comictagger.desktop
  install -Dm644 comictaggerlib/graphics/app.png "${pkgdir}"/usr/share/icons/comictagger.png
}