PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90

# Maintainer: abelian424

_pkgname="como"
pkgname="$_pkgname"
pkgver=0.1.0
pkgrel=2
pkgdesc='Library collection to easily create Wayland and X11 compositors'
url="https://github.com/winft/como"
license=('LGPL-2.1-only')
arch=('x86_64' 'aarch64')

depends=(
  kauth
  kconfigwidgets
  kdecoration
  kquickcharts
  libepoxy
  libqaccessibilityclient-qt6
  qt6-5compat
  qt6-declarative
  qt6-tools
  wlroots

  # AUR
  wrapland

  ## implicit
  #hicolor-icon-theme
  #kcmutils
  #kcolorscheme
  #kconfig
  #kcoreaddons
  #kglobalaccel
  #ki18n
  #kidletime
  #kirigami
  #kpackage
  #kservice
  #ksvg
  #kwidgetsaddons
  #kwindowsystem
  #libinput
  #libplasma
  #libx11
  #libxcb
  #libxkbcommon
  #qt6-base
  #wayland
  #xcb-util-image
  #xcb-util-keysyms
)
makedepends=(
  extra-cmake-modules
  git
  kdoctools
  ninja
)

provides=("kwin")
conflicts=("kwin")

_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=(
  "$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext"
)
sha256sums=(
  '49d9b8b8b8197f4443f8eae71db8adecf51da73c221a4712d0d8cc46b9fdc09f'
)

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DCMAKE_INSTALL_LIBDIR='lib'
    -DCMAKE_INSTALL_LIBEXECDIR="lib/$_pkgname"
    -DBUILD_TESTING=OFF
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}