blob: 4fa5f8d787e00127a768b7d2111501239e240409 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Stefan Wimmer <info@stefanwimmer128.xyz>
# Contributor: Lancelot Owczarczak <lancelot@owczarczak.fr>
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
pkgname=compiler-rt17
pkgver=17.0.6
pkgrel=1
pkgdesc="Compiler runtime libraries for clang 17"
arch=('x86_64')
url="https://compiler-rt.llvm.org/"
license=('custom:Apache 2.0 with LLVM Exception')
depends=('gcc-libs')
makedepends=('llvm17' 'cmake' 'ninja' 'python')
# Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
makedepends_x86_64=('lib32-gcc-libs')
options=('staticlibs')
_source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
source=($_source_base/compiler-rt-$pkgver.src.tar.xz
$_source_base/cmake-$pkgver.src.tar.xz)
sha256sums=('11b8d09dcf92a0f91c5c82defb5ad9ff4acf5cf073a80c317204baa922d136b4'
'807f069c54dc20cb47b21c1f6acafdd9c649f3ae015609040d6182cab01140f4')
prepare() {
mv cmake{-$pkgver.src,}
cd compiler-rt-$pkgver.src
mkdir build
}
build() {
cd compiler-rt-$pkgver.src/build
local cmake_args=(
-G Ninja
-DCMAKE_BUILD_TYPE=Release
-DCMAKE_INSTALL_PREFIX=/usr/lib/llvm17
-DCMAKE_SKIP_RPATH=ON
-DCOMPILER_RT_INSTALL_PATH=/usr/lib/llvm17/lib/clang/${pkgver%%.*}
)
cmake .. "${cmake_args[@]}"
ninja
}
package() {
cd compiler-rt-$pkgver.src/build
DESTDIR="$pkgdir" ninja install
install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|