blob: 0d082e507a850f1e96a783554c003220598c3353 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>
# Maintainer: Shohei Maruyama <cheat.sc.linux@outlook.com>
# Contributor: Bram Swenson <bram@amplified.work>
pkgbase='concourse-git'
pkgname=('concourse-git' 'concourse-fly-cli-git')
pkgver=v7.9.0.r17.gf3cb492d1
pkgrel=3
arch=('x86_64')
url='https://concourse-ci.org'
license=('custom:Apache-2.0')
source=("git+https://github.com/concourse/concourse.git")
makedepends=('go' 'yarn')
sha256sums=('SKIP')
pkgver() {
cd "${pkgbase%-git}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgbase%-git}"
mkdir -p "${srcdir}/go"
export GOPATH="${srcdir}/go"
export PATH=$PATH:"$GOPATH/bin"
# Change binary asset directory
sed -e 's#binariesDir = "/usr/local/concourse/bin"#binariesDir = "/usr/lib/cni"#' -i worker/runtime/cni_network.go
sed -e 's#"cni-plugins-dir" default:"/usr/local/concourse/bin"#"cni-plugins-dir" default:"/usr/lib/cni"#' -i worker/workercmd/worker_linux.go
sed -e 's#/usr/local/concourse/bin/init#/usr/lib/concourse/bin/init#' -i worker/runtime/spec/mounts.go
sed -e 's#"init-bin" default:"/usr/local/concourse/bin/init"#"init-bin" default:"/usr/lib/concourse/bin/init"#' -i worker/workercmd/worker_linux.go
go get -d ./...
yarn
}
build() {
cd "${pkgbase%-git}"
export GOPATH="${srcdir}/go"
export PATH=$PATH:"$GOPATH/bin"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
concourse_version=$(git describe --abbrev=0 --tags)
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -ldflags=-X=github.com/concourse/concourse.Version=${concourse_version} -mod=readonly -modcacherw"
yarn build
go build -o concourse ./cmd/concourse
go build -o fly ./fly
gcc -O2 -static cmd/init/init.c -o init
}
package_concourse-git() {
pkgname=concourse-git
pkgdesc="Concourse is a container-based continuous thing-doer written in Go and Elm"
optdepends=('cni-plugins' 'containerd' 'postgresql' 'concourse-resource-types')
conflicts=('concourse-bin' 'concourse')
cd "${pkgbase%-git}"
install -Dm755 concourse "${pkgdir}/usr/bin/concourse"
install -Dm755 init "${pkgdir}/usr/lib/concourse/bin/init"
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}
package_concourse-fly-cli-git() {
pkgname=concourse-fly-cli-git
pkgdesc="A command line interface that runs a build in a container with ATC"
conflicts=('concourse-fly' 'concourse-fly-bin' 'concourse-fly-git' 'fly-cli' 'concourse-fly-cli')
cd "${pkgbase%-git}"
install -Dm755 "fly/fly" "${pkgdir}/usr/bin/fly"
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}
|