blob: 6b83837b0ac1941c5d9ecaa9e4b60c91abd97a07 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Maintainer: mrdotx <klassiker@gmx.de>
# Contributor: Hendrik Schick <hendrik@hndrkk.sh>
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Amanoel Dawod <amoka at amanoel dot com>
# Contributor: Beini <bane@iki.fi>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>
_pkgname=conky
pkgname=conky-git
pkgver=1.18.3.r14.ga9cecaf9
pkgrel=3
pkgdesc='Lightweight system monitor for X'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('x86_64')
makedepends=(
'cmake'
'docbook2x'
'docbook-xsl'
'man-db'
'git'
'catch2'
'pandoc'
'python-yaml'
'python-jinja'
)
depends=(
'glibc'
'glib2'
'lua'
'wireless_tools'
'libxdamage'
'libxinerama'
'libxft'
'imlib2'
'libxml2'
'libpulse'
'libxnvctrl'
'systemd-libs'
'ncurses'
'curl'
'libncursesw.so'
'libXNVCtrl.so'
'libsystemd.so'
'libpulse.so'
'libcurl.so'
)
provides=('conky')
conflicts=('conky')
source=('git+https://github.com/brndnmtthws/conky.git')
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgname"
# Unbundle catch2 to fix build with glibc 2.35
rm -r tests/catch2
ln -s /usr/include/catch2 tests
}
build() {
cd "$_pkgname"
cmake \
-B build \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
-D MAINTAINER_MODE=ON \
-D BUILD_DOCS=ON \
-D BUILD_WLAN=ON \
-D BUILD_XDBE=ON \
-D BUILD_XSHAPE=ON \
-D BUILD_IMLIB2=ON \
-D BUILD_CURL=ON \
-D BUILD_RSS=ON \
-D BUILD_NVIDIA=ON \
-D BUILD_WEATHER_METAR=ON \
-D BUILD_PULSEAUDIO=ON \
-D BUILD_JOURNAL=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
-Wno-dev \
-S .
make -C build
}
package() {
cd "$_pkgname"
make -C build DESTDIR="$pkgdir" install
install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$_pkgname"
install -Dm644 extras/vim/syntax/conkyrc.vim.j2 -t \
"$pkgdir"/usr/share/vim/vimfiles/syntax/
install -Dm644 extras/vim/ftdetect/conkyrc.vim -t \
"$pkgdir"/usr/share/vim/vimfiles/ftdetect/
}
|