summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f3294c07c107214a8f94b80608c73be0cae24336 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
# Maintainer  : Yiannis A Ginis <drxspace[at]gmail[dot]com>
# Contributor : Chris Sakalis <chrissakalis[at]gmail[dot]com>

pkgname=conky-lua-archers-git
_pkgname=conky
pkgver=3156.271ca6d
pkgrel=1
pkgdesc="A free, light-weight system monitor for X with lua enabled for Arch based distros"
arch=('i686' 'x86_64')
url="https://github.com/brndnmtthws/conky/"
license=('GPL3' 'BSD')
replaces=('torsmo' 'conky')
conflicts=('conky' 'conky-lua' 'conky-lua-arch' 'conky-lua-nv' 'conky-lua-archers')
provides=('conky')
depends=(
	'alsa-lib'
	'cairo'
	'curl'
	'glib2'
	'imlib2'
	'librsvg'
	'libxdamage'
	'libxft'
	'libxinerama'
	'libxml2'
	'libxnvctrl'
	'lua51'
	'tolua++'
	'wireless_tools'
)
makedepends=(
	'cmake'
	'docbook2x'
	'docbook-xml'
	'docbook-xsl'
	'perl-xml-libxml'
	'perl-xml-sax-expat'
)
source=("git://github.com/brndnmtthws/${_pkgname}.git"
	'asciime.patch')
sha1sums=('SKIP'
	  'b07407c2be11cee7bd50e046024b89cf2579c448')
options=('!strip' 'debug')

pkgver() {
	cd "${srcdir}/${_pkgname}"
	echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${srcdir}/${_pkgname}"
	patch -p1 -i ../asciime.patch # db2x_manxml fails on non-ascii chars
	mkdir -p build/               # as @afaikifreedom recommended
}

build() {
	cd "${srcdir}/${_pkgname}/build"
	cmake \
		-D CMAKE_BUILD_TYPE=Release \
		-D CMAKE_INSTALL_PREFIX=/usr \
		-D MAINTAINER_MODE=ON \
		-D BUILD_BUILTIN_CONFIG=ON \
		-D BUILD_APCUPSD=ON \
		-D BUILD_ARGB=ON \
		-D BUILD_CURL=ON \
		-D BUILD_I18N=ON \
		-D BUILD_IBM=OFF \
		-D BUILD_IMLIB2=ON \
		-D BUILD_IOSTATS=ON \
		-D BUILD_IPV6=ON \
		-D BUILD_LUA_CAIRO=ON \
		-D BUILD_LUA_IMLIB2=ON \
		-D BUILD_LUA_RSVG=ON \
		-D BUILD_MOC=OFF \
		-D BUILD_MPD=OFF \
		-D BUILD_NVIDIA=ON \
		-D BUILD_OLD_CONFIG=ON \
		-D BUILD_PULSEAUDIO=ON \
		-D BUILD_WLAN=ON \
		-D BUILD_X11=ON \
		-D BUILD_XDAMAGE=ON \
		-D BUILD_XDBE=ON \
		-D BUILD_XFT=ON \
		-D BUILD_XINERAMA=ON \
		-D DEFAULTNETDEV=enp7s4 \
		-D OWN_WINDOW=ON \
		..
	make
}

package() {
	cd "${srcdir}/${_pkgname}/build"
	make DESTDIR=${pkgdir} install
	cd ..
	install -D -m644 LICENSE.GPL ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.GPL
	install -D -m644 LICENSE.BSD ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.BSD
	install -D -m644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
	install -D -m644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}