blob: a104341901a09be052cb4e5f72c7afdf7161bafe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="containerlab"
pkgver=0.74.0
pkgrel=1
pkgdesc="Container-based networking labs"
arch=(
'aarch64'
'x86_64'
)
url="https://containerlab.dev"
_url="https://github.com/srl-labs/${pkgname}"
license=(
'BSD-3-Clause'
)
depends=(
'glibc'
)
makedepends=(
'go'
'git'
)
_pkgsrc="${_url##*/}"
source=(
"${_pkgsrc}::git+${_url}.git#tag=v${pkgver}"
"${pkgname}.sysusers"
)
b2sums=('4c181d4e42aed0ab657f0ee1ff5a4bf2c6e9176f730dcefd7c1f8c9aa966c4b48fb91006893644aecbe8e9cbc947b0bdc6b7528d2d0f76c010cee7b3262132fb'
'7b0465b94085ad1a63e7a9a7fcf5598c68dd847de4151197fa850032bb4a1265575c8f08c66318fe062bea70a67465e8547a2f941bb628f1a6bf6bb4958540e4')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -modcacherw -x
mkdir -p "build" "completions"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
local build_commit="$(git rev-parse --short HEAD)"
local build_date="$(date --utc --date="@${SOURCE_DATE_EPOCH:-$(date +%s)}" +"%Y-%m-%dT%H:%M:%SZ")"
go build -v -o "build/${pkgname}" -ldflags "\
-X ${_url#https://}/cmd.Version=${pkgver} \
-X ${_url#https://}/cmd.commit=${build_commit} \
-X ${_url#https://}/cmd.date=${build_date}" \
.
for _sh in bash fish zsh; do
./"build/${pkgname}" completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}"
install -vDm644 "${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
cd "${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
find "lab-examples" -type f ! -name '.gitignore' -exec \
install -Dm644 "{}" "${pkgdir}/usr/share/doc/${pkgname}/{}" \;
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
}
|